我的wincc授权过期了，重新授权后打开wincc报下列授权未安装或不充分。Simatic WinCC RC (Runtime + Development)，这个是那个授权啊
钻石用户推荐最佳答案
1、首先要删除原来的授权，把过期的授权删除。
2、删除AX NF ZZ文件夹里面的内容。
把每个盘符根目录下的都删除。
如果看不到这个文件夹，就按照步骤3或者步骤4操作
3、显示隐藏文件和系统文件。
4、或者利用下面我的批处理，运行批处理，根据提示选择就行。
@echo off
title 文件显示/隐藏工具
:start
::清除屏幕显示
cls
echo *******************************************
echo.
echo 欢迎使用隐藏和显示文件工具
echo.
echo 请选择功能:
echo 【1】 显示隐藏文件
echo 【2】 不显示隐藏文件
echo 【3】 显示受系统保护的文件
echo 【4】 不显示受系统保护的文件
echo 【5】 显示已知文件类型扩展名
echo 【6】 不显示已知文件类型扩展名
echo 【0】 退出
echo.
echo Author : volcanol
echo Email ：lilinly225@126.com
echo.
echo ********************************************
echo.
::通过set命令获取用户输入
set /p choice=请输入您的选择:
::根据不同的选择跳转到不同的IP设置程序段
if "%choice%"=="1" goto display_hided_files
if "%choice%"=="2" goto hide_hided_files
if "%choice%"=="3" goto display_system_protect_files
if "%choice%"=="4" goto hide_system_protect_files
if "%choice%"=="5" goto display_file_extension_name
if "%choice%"=="6" goto hide_file_extension_name
if "%choice%"=="0" goto exit_tools
echo.
echo 您的输入不正确，按任意键继续……
::通过重定向将pause的输出定向到其他位置，nul表示输出到空文件
::将不会显示任何内容，也不会生成新的文件
pause>nul
goto start
:display_hided_files
::修改注册表数据项 用于显示隐藏文件
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v Hidden /t reg_dword /d 1 /f
goto start
:hide_hided_files
::修改注册表项目 用于隐藏文件
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v Hidden /t reg_dword /d 0 /f
goto start
:display_system_protect_files
::修改注册表项目 用于显示受系统保护的文件
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v ShowSuperHidden /t reg_dword /d 1 /f
goto start
:hide_system_protect_files
::修改注册表项目 用于隐藏受系统保护的文件
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v ShowSuperHidden /t reg_dword /d 0 /f
goto start
:display_file_extension_name
::修改注册表项目 用于显示文件扩展名
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v HideFileExt /t reg_dword /d 0 /f
goto start
:hide_file_extension_name
::修改注册表项目 用于隐藏文件扩展名
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v HideFileExt /t reg_dword /d 1 /f
goto start
:exit_tools
exit
上面内容，复制到txt文件，改名扩展名.bat的文件就可以。
提问者对于答案的评价：
原创文章，作者：ximenziask，如若转载，请注明出处：https://www.zhaoplc.com/plc363468.html
微信扫一扫 
支付宝扫一扫 